VAR stein_dabei = false
VAR feder_dabei = false
VAR flasche_dabei = false
VAR papierrolle_dabei = false

-> wald

=== wald ===
// Beim ersten Betreten des Knoten "wald" wird nun "Du wachst auf in einem Wald..." sein. Beim zweiten Betreten kommt "Möchtest Du weitere Gegenstände in Augenschein nehmen."
// Dieser variierende Text funktioniert so:
// {Text beim ersten Betreten | Text beim zweiten Betreten | Text bei jedem weiteren Betreten}
// (Variierender Text bietet noch mehr Möglichkeiten, dazu werde ich eine Lektion schreiben...)
// Leider funktioniert das nur, wenn {variante a | variante b | variante c} in einer Zeile steht.
// Deshalb habe ich mit <br> Zeilenumbrüche eingefügt.

{Du wachst auf in einem Wald, der in geheimnisvolles Dämmerlicht getaucht ist. Du liegst auf weichem Moos. Du bist noch ganz benommen und hast keine Ahnung, wie Du hierher gekommen bist. <br> <br> Du stehst auf und siehst Dich um. Du siehst verschiedene Gegenstände herumliegen. Welchen willst Du genauer ansehen?|Möchtest Du weitere Gegenstände in Augenschein nehmen?}

// Hier ist jetzt, (anstatt eine Auswahl nur einmal zu erlauben mit *) eine bedingte Anzeige.
// + {bedingung} [Wahl] bedeutet: Nur wenn die Bedingung wahr ist, soll die Auswahl angezeigt werden.
// Da wir wollen, dass [Stein] nur angezeigt wird, wenn die Bedingung NICHT wahr ist, schreiben wir ein "not" davor:
+ {not stein_dabei} [Stein]
    -> stein

+ {not flasche_dabei} [Flasche]
    -> flasche
    
+ {not papierrolle_dabei} [Papierrolle]
    -> papierrolle
    
+ {not feder_dabei} [Feder]
    -> feder
    
// Wenn wir alle Gegenstände eingesteckt haben, könnte es sein, dass es an dieser Stelle keine Auswahlmöglichkeiten mehr gibt! Das würe einen Fehler bzw. ein "totes Ende" produzieren.
// Das fangen wir mit dem folgenden Code ab:
+ ->
    Es liegen keine Gegenstände mehr herum.
    -> wald_verlassen


= stein
Du schaust Dir den Stein an. Darauf sind geheimnisvolle Runen eingeritzt.

Was möchtest Du tun?
+ [Stein einstecken]
    ~ stein_dabei = true
    -> wald
+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen

= flasche
Die Flasche ist leer, aus blauem, dickwandigem Glas und ist mit einem Korken verschlossen.
+ [Flasche einstecken]
    ~ flasche_dabei = true
    -> wald
+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen

= feder
Die Feder ist schwarz-blau glänzend.
+ [Feder einstecken]
    ~ feder_dabei = true
    -> wald
+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen
    
= papierrolle
Auf der Papierrolle steht folgender Text:
    
"Dies ist ein Rezept für einen Zaubertrank, der Dir Dein Gedächtnis wiedergibt.
Du benötigst dafür folgende Zutaten:
Zauberkraut
Goldene Tautropfen
Einhornträne"

Was willst Du tun?

+ [Die Papierrolle einstecken]
    ~ papierrolle_dabei = true

+ [Weiter schauen]
    
+ [Weitergehen]
    -> wald_verlassen
    
--> wald
    
=== wald_verlassen ===
In welche Richtung willst Du weitergehen?
+ [Richtung Norden, wo sich ein Moor befindet] // Zauberkraut
    -> moor
+ [Richtung Osten, in die Regenbogenwelt]  // Einhorntränen
    -> regenbogen_welt
+ [Richtung Süden, in die Wüste] // Monster oder weitere Aufgabe...
    -> wueste
+ [Richtung Westen, tiefer in den Wald hinein] // See, Tautropfen
    -> END

=== moor ===
// Kristinas Bereich //

Du bewegst Dich Richtung Norden, siehst immer noch den Wald, und spürst, dass der Boden unter Dir immer weicher wird. Ausserdem fängt es an zu stinken.

Was willst Du tun?

+ [Einfach weitergehen]
    Das war keine kluge Entscheidung. Du versinkst im Moor. Dein Abenteuer endet hier.
    -> END
    
+ [Zurückgehen]
    Du bist wieder auf der Waldlichtung.
    -> wald_verlassen
    
+ [Stehenbleiben und abwarten]
   
Ein Zwerg erscheint.
  -> zwerg

=== zwerg ===
Der Zwerg sagt: {"Was machst du hier?".|"Was willst Du schon wieder?"|"Schon wieder Du, langsam wird es langweilig, was gibt's?"|"Seufz. Was ist los, was möchtest Du?"}

Was antwortest du ihm?
   
+ [gar nichts.]
Du antwortest dem Zwerg, dass du hier nichts machen würdest.
    
"Wenn du hier nichts machst",antwortet der Zwerg,"dann scher dich
aus meinem Moor!"

Du gehst zurück zur Waldlichtung.
 -> wald_verlassen

+ [Ich überlege, wie ich über das Moor komme.]
    
Du sagst dem Zwerg, dass du überlegst, wie du über das Moor gelangst.
    
"Warum willst du denn über das Moor?", fragt der Zwerg.

- Was sagst du ihm?
   
+ [geht ihn nichts an]
   
Du antwortest:"Das ist meine Sache, die dich nichts angeht.

"Wenn das mich nichts angeht",antwortet der Zwerg,"dann scher
dich aus meinem Moor!"

Du gehst zurück zur Waldlichtung.
  -> wald_verlassen
      
+ [Ich suche goldene Tautropfen.]
    
Ich suche hier nach goldenen Tautropfen. Weißt du wo ich die finden
kann?
  -> dialog_tautropfen
    
= dialog_tautropfen

"Goldene Tautropfen, sagst du? Weil du ehrlich bist, werde ich dir helfen.", antwortet der Zwerg.

"Die Tautropfen befinden sich direckt hinter dem Moor, auf einer besonderen Wiese. Dort hängen die Tautropfen auf den Halmen der Pflanzen. Um sie golden zu färben, musst du die Sonnenstrahlen der untergehenden Sonne auf sie lenken."

"Vielen lieben Dank für alle Informationen. Das werde ich dir nicht vergessen. Kannst du mir bitte helfen, über das Moor zu kommen?", antworterst du.

Der Zwerg entgegnet:"Wenn du mich beim Versteckenspieln findest, dann bringe ich dich über das Moor. Aber wenn nicht, dann wirst du bei mir bleiben und mir zwei Jahre dienen."
   
+ [Ja]
   
Ja, wir machen einen Deal.
   
  -> verstecken
   
+ [Nein]
   
Du sagst: "Nein,das möchte ich nicht."

Der Zwerg antwortet: "Dann verlasse mein Moor, denn ich habe viele andere Dinge zu erledigen."

Du gehst zurück zur Waldlichtung.
  -> wald_verlassen
    
= verstecken
  -> END

=== regenbogen_welt ===  
// Annikas Bereich //

Du gehst in Richtung Osten und kommst in eine bunte Welt voller Fabelwesen wie zum Beispiel Drachen, Pegasus, Kobolde, Trolle... aber du siehst keine Einhörner.

Auf einmal siehst  du einen Kleinen Wald dort siehst du kleine Pegasus Kinder. Da drehst du dich noch ein mal um und siehst einen kleinen Teich und ziemlich viele Seen drumherum.

Alle Seen sind bunt nur der kleine Teich ist Lila.

Was willst Du tun?

* [In den Wald gehen]
  -> regenbogen_wald
    
+ [Zurückgehen]
  -> wald_verlassen
    
* [Zu dem Teich und den Seen]
  -> regenbogen_see

= regenbogen_wald
Du gehst in den Wald und siehst eine kleine Diamantene, amethystfarbene Flasche.
  -> END
    
= regenbogen_see
Du gehst zu dem Teich und siehst auf einmal ei wunderschönes Einhorn, aber da kam noch ein viel schöneres Einhorn dass sogar Flügel hatte (in deiner Fantasie geht alles zwinkernd)
  ->END
    
=== wueste ===
// Tobias' Bereich //
  -> END

Zuletzt geändert: Freitag, 15. November 2024, 11:26