Stand 10.10.24

VAR anzahl_gegenstaende = 0

VAR stein_dabei = false
VAR feder_dabei = false
VAR flasche_dabei = false
VAR papierrolle_dabei = false

-> wald

=== wald
// Beim ersten Betreten des Knoten "wald" wird nun "Du wachst auf in einem Wald..." sein. Beim zweiten Betreten kommt "Möchtest Du weitere Gegenstände in Augenschein nehmen."
// Dieser variierende Text funktioniert so:
// {Text beim ersten Betreten | Text beim zweiten Betreten | Text bei jedem weiteren Betreten}
// (Variierender Text bietet noch mehr Möglichkeiten, dazu werde ich eine Lektion schreiben...)
// Leider funktioniert das nur, wenn {variante a | variante b | variante c} in einer Zeile steht.
// Deshalb habe ich mit <br> Zeilenumbrüche eingefügt.

{Du wachst auf in einem Wald, der in geheimnisvolles Dämmerlicht getaucht ist. Du liegst auf weichem Moos. Du bist noch ganz benommen und hast keine Ahnung, wie Du hierher gekommen bist. <br> <br> Du stehst auf und siehst Dich um. Du siehst verschiedene Gegenstände herumliegen. Welchen willst Du genauer ansehen?|Möchtest Du weitere Gegenstände in Augenschein nehmen?}

// Hier ist jetzt, (anstatt eine Auswahl nur einmal zu erlauben mit *) eine bedingte Anzeige.
// + {bedingung} [Wahl] bedeutet: Nur wenn die Bedingung wahr ist, soll die Auswahl angezeigt werden.
// Da wir wollen, dass [Stein] nur angezeigt wird, wenn die Bedingung NICHT wahr ist, schreiben wir ein "not" davor:
+ {not stein_dabei} [Stein]
    -> stein

// Mit der Flasche ist es etwas komplizierter. Hier müssen wir ZWEI Bedingungen prüfen.
// Die sind mit einem "and" verknüpft:
+ {(not papierrolle_dabei) and (not flasche_dabei)} [Flasche]
    -> flasche
// Die Flasche mit der darin enthaltenen Schriftolle ist ein ziemlich kompliziertes Objekt1
// Ich denke, wir sollten das vereinfachen bzw. übersichtlicher gestalten.
// Wir könnten, wenn wir nur die Papierrolle eingesteckt haben, eine neue Auswahl "Leere Flasche" anbieten.
// Oder die Flasche beim Öffnen zerbrechen lassen. Naja, dann müssten Glasscherben herumliegen.
// Wir überlegen das nächstes Mal gemeinsam!

+ {not feder_dabei} [Feder]
    -> feder
    
// Wenn wir alle Gegenstände eingesteckt haben, könnte es sein, dass es an dieser Stelle keine Auswahlmöglichkeiten mehr gibt! Das würe einen Fehler bzw. ein "totes Ende" produzieren.
// Das fangen wir mit dem folgenden Code ab:
+ ->
    Es liegen keine Gegenstände mehr herum.
    -> wald_verlassen


= stein
Du schaust Dir den Stein an. Darauf sind geheimnisvolle Runen eingeritzt.

Was möchtest Du tun?
+ [Stein einstecken]
    ~ stein_dabei = true
    -> wald
+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen

= flasche
Die Flasche beinhaltet einen Stift und eine Papierrolle.
Was möchtest Du tun?
+ [Flasche öffnen]
    -> papierrolle


+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen

= feder
Die Feder ist schwarz-blau glänzend.
+ [Feder einstecken]
    ~ feder_dabei = true
    -> wald
+ [Weiter schauen]
    -> wald
+ [Weitergehen]
    -> wald_verlassen
    
= papierrolle
Dir fällt eine Papierrolle in die Hand, und Du siehst Dir den Text darauf an:
    
"Dies ist ein Rezept für einen Zaubertrank, der Dir Dein Gedächtnis wiedergibt.
Du benötigst dafür folgende Zutaten:
Zauberkraut
Goldene Tautropfen
Einhornträne"

Was willst Du tun?
+ [Die Flasche einstecken]
    ~ flasche_dabei = true

+ [Die Papierrolle einstecken]
    ~ papierrolle_dabei = true

+ [Beides einstecken]
    ~ flasche_dabei = true
    ~ papierrolle_dabei = true

+ [Weiter schauen]
    
+ [Weitergehen]
    -> wald_verlassen
    
--> wald
    
=== wald_verlassen ===
In welche Richtung willst Du weitergehen?
+ [Norden]
-> END
+ [Osten]
-> END
+ [Süden]
-> END
+ [Westen]
-> END